Bat que mostra a versão de um EXE

Iae Galera
Alguém sabe alguma sintaxe pra ver a a versão de um determinado EXE e lançar em uma variável ?

Código:

@echo off
set arquivo="C:\Program Files\Microsoft Office\Office14\MSACCESS.EXE"
set arquivo=%arquivo:\=\\%
FOR /F "tokens=2 delims==" %%I in ('"wmic datafile where^(name^=%arquivo%^) get version /format:list"') DO (SET "RESULT=%%I")
ECHO Versao do arquivo = %RESULT%
pause

"C:\Program Files\Microsoft Office\Office14\MSACCESS.EXE"
mude para o nome e caminho do arquivo que você quer saber a versão 

wmic datafile where name="C:\\Program Files\\Microsoft Office\\Office14\\MSACCESS.EXE" get version /format:list

mesma coisa

esse usa o java e é mais completo

Código:

@Echo off
(
Echo.@if (@X^)==(@Y^) @end /* JScript comment
Echo.@echo off
Echo.cscript //E:JScript //nologo "%%~f0" %%*
Echo.exit /b %%errorlevel%%
Echo.@if (@X^)==(@Y^) @end JScript comment */
Echo.//////
Echo.FSOObj = new ActiveXObject("Scripting.FileSystemObject"^);
Echo.var ARGS = WScript.Arguments;
Echo.if (ARGS.Length ^< 1 ^) {
Echo.WScript.Echo("Arquivo não encontrado"^);
Echo.WScript.Quit(1^);
Echo.}
Echo.var filename=ARGS.Item(0^);
Echo.var objShell=new ActiveXObject("Shell.Application"^);
Echo./////
Echo.//fso
Echo.ExistsItem = function (path^) {
Echo.return FSOObj.FolderExists(path^)^|^|FSOObj.FileExists(path^);
Echo.}
Echo.getFullPath = function (path^) {
Echo.return FSOObj.GetAbsolutePathName(path^);
Echo.}
Echo.//
Echo.//paths
Echo.getParent = function(path^){
Echo.var splitted=path.split("\\"^);
Echo.var result="";
Echo.for (var s=0;s^<splitted.length-1;s++^){
Echo.if (s==0^) {
Echo.result=splitted[s];
Echo.} else {
Echo.result=result+"\\"+splitted[s];
Echo.}
Echo.}
Echo.return result;
Echo.}
Echo.getName = function(path^){
Echo.var splitted=path.split("\\"^);
Echo.return splitted[splitted.length-1];
Echo.}
Echo.//
Echo.function main(^){
Echo.if (!ExistsItem(filename^)^) {
Echo.WScript.Echo(filename + " does not exist"^);
Echo.WScript.Quit(2^);
Echo.}
Echo.var fullFilename=getFullPath(filename^);
Echo.var namespace=getParent(fullFilename^);
Echo.var name=getName(fullFilename^);
Echo.var objFolder=objShell.NameSpace(namespace^);
Echo.var objItem=objFolder.ParseName(name^);
Echo.//https://msdn.microsoft.com/en-us/library/windows/desktop/bb787870(v=vs.85^).aspx
Echo.WScript.Echo(fullFilename + " : "^);
Echo.WScript.Echo(objFolder.GetDetailsOf(objItem,-1^)^);
Echo.}
Echo.main(^);
)>Versao.BAT


set arquivo="C:\Program Files\Microsoft Office\Office14\MSACCESS.EXE"
call Versao.BAT %arquivo%
pause


Boss valeu mesmo!! também estava procurando isso algum tempo atrás...
Sim Boss eu já conhecia o comando "wmic" já tinha olhado o help dele mas tem um problema eu nunca tinha visto esse comando "Where" como você descobriu isso cara você é um ninja 'kkkk
Até fica com Deus!

Show,
Valeu mesmo, tu é o cara!